[转载]PROC REPORT基础

浏览: 2525

1 PROC REPORT语法

PROC REPORT  data= SAS-data-set  options ;

   COLUMNS variable_1 …. variable_n;

   DEFINE variable_1;

   DEFINE variable_2;

  . . .

 DEFINE variable_n;

 COMPUTE  blocks 

  BREAK … ;

  RBREAK … ; 

 RUN;

COLUMNS：指定输出到报表的列

DEFINE：上述列的格式等

COMPUTE：计算模块

BREAK / RBREAK：生成合计，或报表其它类型的格式。

 

PROC REPORT的选项Options有很多，下面介绍几个常用的：

DATA= 指定做报表的数据集

PROMPT= PROMPT模式

NOWINDOWS= 不输出到结果

REPORT = 指定一个存储的报表来生成新报表

OUTREPT= 指定新路径来存放报表

OUT=  建立新数据集

HEADLINE 在报表变量标题和内容间生成一个水平分隔线

HEADSKIP 在报表变量标题和内容间生成一行空格

 

2 先生成一个基本的报表

先生成数据：

 data mnthly_sales;                  

   length zip $ 5 cty $ 8 var $ 10; 

   input zip $ cty $ var $ sales;    

   label zip="Zip Code"             

         cty="County"                

         var="Variety"               

         sales="Monthly Sales";      

   datalines;                        

 52423 Scott Merlot 186.             

 52423 Scott Chardonnay 156.61       

 52423 Scott Zinfandel 35.5          

 52423 Scott Merlot 55.3              

 52388 Scott Merlot 122.89           

 52388 Scott Chardonnay 78.22        

 52388 Scott Zinfandel 15.4          

 52200 Adams Merlot 385.51           

 52200 Adams Chardonnay 246          

 52200 Adams Zinfandel 151.1         

 52200 Adams Chardonnay 76.24       

 52199 Adams Merlot 233.03          

 52199 Adams Chardonnay 185.22      

 52199 Adams Zinfandel 95.84        

 ;              

run;

 

Proc Report生成最基本的报表：

proc report data=mnthly_sales  

    headline headskip ;   

   title1 "Simple Report";

   column cty zip var sales;            

   define cty / display  width=6 'County/Name';

   define zip / display;               

   define var / display;               

   define sales / display format=6.2 width=10;

run;    

这里的define后面的’/’，其后面有很多选项来对变量格式，输出方式等进行设置，其选项如下：

GROUP：分组显示

DISPLAY：一般显示

ANALYSIS：其值用于计算或统计

ORDER：按其值排序显示

ACROSS：交叉显示

COMPUTED：其值在compute块里计算得到

 

结果：

 Clipboard Image.png


3 使用order，按指定变量名排序显示

proc report data=mnthly_sales 

    headline headskip ;   

   title1 "Simple Report";             

   column cty zip var sales;           

   define cty / order  width=6 'County/Name';               

   define zip / display;               

   define var / display;                

   define sales / display format=6.2 width=10;             

 run;    

结果：

Clipboard Image.png

4 group分组显示

proc report data=mnthly_sales  nofs

    headline headskip ;   

   title1 "Simple Report";             

   column cty zip var sales;           

   define cty / group   width=6 'County/Name';               

   define zip /  group;                

   define var /  group order=freq descending;

   define sales / display format=6.2 width=10;             

 run;    

         

结果：

Clipboard Image.png

5 analysis，统计量求和

proc report data=mnthly_sales  nofs

    headline headskip ;   

   title1 "Simple Report";             

   column cty zip   sales;           

   define cty / group   width=6 'County/Name';               

   define zip /  group;                              

   define sales / analysis sum  format=6.2 width=10;             

 run; 

结果：

Clipboard Image.png

6 求多个统计量

proc report data=mnthly_sales  nofs

    headline headskip ;   

   title1 "Simple Report";             

   column cty zip sales sales=mean_sales;           

   define cty / group   width=6 'County/Name';               

   define zip /  group;                              

   define sales / analysis sum  format=6.2 width=10 'sum';

    define mean_sales / analysis mean   format=6.2 width=10 'Mean of/Sales';

 run;    

结果：

Clipboard Image.png

7   变量值作为一类列 

如果你想让某变量的每一个值都作为一列，那就要用到across。这里要注意的是，有across选项的var，在column时后面加了一个’,’，从而将其后面的变量的数据直接放到across变量下。。

proc report data=mnthly_sales nofs headline headskip;

   title1 "Cross Tab Report (Across Type)";

   column cty zip var,sales;

   define cty / group width=6 'County/Name';

   define zip / group;

   define var / across order=freq descending '- Grape Variety -';

   define sales / analysis sum format=6.2 width=10 'Revenue';

 run;

结果：

Clipboard Image.png

这里，变量variety的每一个值都成为了新的列

 

8  BREAK与RBREAK，对分组后的报表汇总

proc report data=mnthly_sales nofs headline headskip;

   title1 "Report with Breaks";

   column cty zip var,sales;

   define cty / group width=6 'County/Name';

   define zip / group;

   define var / across order=freq descending '- Grape Variety -';

   define sales / analysis sum format=6.2 width=10 'Revenue';

   break after cty / ol skip summarize suppress;

   rbreak after / dol skip summarize;

 run;

结果：

Clipboard Image.png


这里说明一下BREAK与RBREAK后面的选项：

OL 汇总上方加一条线

DOL汇总上方加两条线

UL汇总下方加一条线 

DUL 汇总下方加两条线

summarize  对每组进行汇总 

skip  加入一空白行

suppress  在汇总行不显示组名

 

9 compute块，计算统计变量

这个以后将专门介绍

proc report data=mnthly_sales nofs headline headskip;

   title1 "Report with Row Sums (Computed Type)";

   column cty zip var,sales row_sum;

   define cty / group width=6 'County/Name';

   define zip / group;

   define var / across order=freq descending '- Grape Variety -';

   define sales / analysis sum format=6.2 width=10 'Revenue';

   define row_sum / computed format=comma10.2 'Total';

   break after cty / ol skip summarize suppress;

   rbreak after / dol skip summarize;

   compute row_sum;

     row_sum = sum(_C3_,_C4_,_C5_,_C6_,_C7_,_C8_);

   endcompute;

 run;

结果：

Clipboard Image.png

Compute块是以compute开始，endcompute为结尾，可以计算出很多复杂的数据。这里的_C*_表示第几列的变量，例如_C3_表示第三列，_C#_代表最后一行。这里的_C7_和_C8_是多余的，但不影响结果。

 

10 proc report与ODS

  以后会详细介绍。这里用ODS输出report过程结果，方法很简单，就是将上面的report代码放入ods语句之间。

ods  listing close; 

ods rtf file = ‘c:sugi30.rtf’; 

       上面的proc report过程代码放在这里就行 

ods rtf close;

即：

 

ods  listing close; 

ods rtf file = 'c:sugi30.rtf'; 

 proc report data=mnthly_sales nofs headline headskip;

   title1 "Report with Row Sums (Computed Type)";

   column cty zip var,sales row_sum;

   define cty / group width=6 'County/Name';

 define zip / group;

   define var / across order=freq descending '- Grape Variety -';

   define sales / analysis sum format=6.2 width=10 'Revenue';

   define row_sum / computed format=comma10.2 'Total';

   break after cty / ol skip summarize suppress;

   rbreak after / dol skip summarize;

   compute row_sum;

     row_sum = sum(_C3_,_C4_,_C5_,_C6_,_C7_,_C8_);

   endcompute;

 run;

 ods rtf close;

结果：

Clipboard Image.png

11 report设置style，让报表更炫一点。

 这个以后也会详细介绍

ods  listing close; 

ods rtf file = 'c:sugi30.rtf'; 

 

 proc report data=mnthly_sales nofs headline headskip 

          style(header)={background=lightskyblue foreground=black}

          style(column)={background=lightcyan foreground=black};

   title1 "Report with Row Sums (Computed Type)";

   column cty zip var,sales row_sum;

   define cty / group width=6 'County/Name';

   define zip / group;

   define var / across order=freq descending '- Grape Variety -';

   define sales / analysis sum format=6.2 width=10 'Revenue';

   define row_sum / computed format=comma10.2 'Total';

   break after cty / ol skip summarize suppress;

   rbreak after / dol skip summarize;

   compute row_sum;

     row_sum = sum(_C3_,_C4_,_C5_,_C6_,_C7_,_C8_);

   endcompute;

 run;

 ods rtf close;

结果：

Clipboard Image.png

推荐 0
本文由 面包君 创作，采用 知识共享署名-相同方式共享 3.0 中国大陆许可协议 进行许可。
转载、引用前需联系作者，并署名作者且注明文章出处。
本站文章版权归原作者及原出处所有 。内容为作者个人观点， 并不代表本站赞同其观点和对其真实性负责。本站是一个个人学习交流的平台，并不用于任何商业目的，如果有任何问题，请及时联系我们，我们将根据著作权人的要求，立即更正或者删除有关内容。本站拥有对此声明的最终解释权。

0 个评论

要回复文章请先登录或注册